# Min - Diagrammfunktion

Min() liefert den niedrigsten Wert der aggregierten Daten. Durch die Festlegung eines rank n kann der niedrigste n-te Wert gefunden werden.

TipphinweisEs ist auch ratsam, sich FirstSortedValue und RangeMin anzusehen. Diese haben eine ähnliche Funktion wie die Funktion Min.

Syntax:

Min({[SetExpression] [TOTAL [<fld {,fld}>]]} expr [,rank])

Rückgabe Datentyp: numerisch

Argumente

| Argument | Beschreibung |
| --- | --- |
| expr | Die Formel oder das Feld mit den Daten, die gemessen werden sollen. |
| rank | Der Standardwert von rank ist 1, was dem niedrigsten Wert entspricht. Durch die Angabe von rank als 2 wird der zweitniedrigste Wert zurückgegeben. Falls rank 3 ist, wird der drittniedrigste Wert zurückgegeben und so weiter. |
| SetExpression | Standardmäßig berechnet sich die Aggregierungsfunktion über alle wählbaren Werte. Alternativ können Sie die der Berechnung zugrunde liegenden Werte über die Auswahlformel bestimmen. |
| TOTAL | Der Zusatz TOTAL vor der Funktion bewirkt, dass die Berechnung über alle ausgewählten bzw. wählbaren Werte erfolgt, und nicht nur über diejenigen, die zu dem Wert der aktuellen Dimension zählen. Die Dimensionen des Diagramms werden also nicht berücksichtigt. Mit TOTAL [&lt;fld {.fld}&gt;], wobei auf den Zusatz TOTAL eine Liste aus mindestens einem Feldnamen (d. h. einer Teilmenge der Diagrammdimensionsvariablen) folgt, erstellen Sie eine Teilmenge aller möglichen Werte.<br><br>[Definieren des Aggregierungsbereichs](https://help.qlik.com/de-DE/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/define-aggregation-scope.htm) |

Beispiel: Diagrammformeln

| Beispiel | Ergebnis |
| --- | --- |
| `Min(UnitSales)` | Gibt den niedrigsten Nicht-Null-Wert im Feld `UnitSales` zurück. |
| `Min(UnitSales*UnitPrice)` Der Wert einer Bestellung wird aus der Anzahl der verkauften Einheiten (`UnitSales`) multipliziert mit dem Stückpreis berechnet. | Gibt den niedrigsten Nicht-Null-Wert der Berechnung aus allen möglichen Werten von (`UnitSales`)\*(`UnitPrice`) zurück. |
| `Min(UnitSales, 2)` | Gibt den Wert für den zweitniedrigsten Wert in `UnitSales` zurück (nach den NULL-Werten). |
| `Min(TOTAL UnitSales)` | Der Qualifizierer `TOTAL` bedeutet, dass der niedrigste mögliche Wert gefunden wird, ohne die Diagrammdimensionen zu berücksichtigen. Bei einem Diagramm mit der Dimension `Customer` sorgt der Qualifizierer `TOTAL` dafür, dass der minimale Wert übergreifend über den vollständigen Datensatz anstelle des Minimalwerts `UnitSales` für jeden Kunden zurückgegeben wird. |
| `Min({1} TOTAL UnitSales)` | Die Formel der Aggregierung mit Auswahlformeln `{1}` definiert den Datensatz so, dass er als `ALL` bewertet wird, unabhängig davon, welche Auswahl getroffen wird. Wenn zum Beispiel ein bestimmter Kunde ausgewählt wird, wird immer noch der minimale `UnitSales` für den gesamten Datensatz angezeigt. |

## Beispiel – Grundlegendes zu „Min“

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/BasicAggregationFunctions/min.htm)

#### Diagrammformel

Übersicht

Öffnen Sie den Dateneditor und fügen Sie das Ladeskript unten in einen neuen Abschnitt ein.

Das Ladeskript umfasst:

* Datensatz, der in eine Datentabelle namens `Example` geladen wird

* Die folgenden Felder in der Datentabelle:

  * `Customer`

  * `UnitSales`

  * `UnitPrice`

Ladeskript

```
Example:
LOAD * inline [
Customer|UnitSales|UnitPrice
Astrida|4|16
Astrida|10|15
Astrida|9|9
Betacab|5|10
Betacab|2|20
Betacab||25
Canutility|8|15
Canutility||19
] (delimiter is '|');
```

Ergebnisse

Laden Sie die Daten und öffnen Sie ein Arbeitsblatt. Erstellen Sie eine neue Tabelle und fügen Sie dieses Feld als Dimension hinzu:

* `Customer`

Erstellen Sie die folgenden Kennzahlen:

* `=Min(UnitSales)`, um den minimalen Wert für `UnitSales` zu berechnen.

* `=Min(UnitSales*UnitPrice)`, um den minimalen Wert nach der Multiplikation von `UnitSales` mit `UnitPrice` zeilenweise zu berechnen.

* `=Min(UnitSales, 2)`, um den zweitniedrigsten Wert zu berechnen.

* `=Min(TOTAL UnitSales)`, um unabhängig von der Diagrammdimension den niedrigsten Gesamtwert zu berechnen.

* `=Min({1} TOTAL UnitSales)`, um den niedrigsten Gesamtwert zu berechnen und alle Auswahlen zu ignorieren.

Results table

| Customer | Min(UnitSales) | Min(UnitSales\*UnitPrice) | Min(UnitSales, 2) | Min(TOTAL UnitSales) | Min({1} TOTAL UnitSales) |
| --- | --- | --- | --- | --- | --- |
| Totals | 2 | 40 | 4 | 2 | 2 |
| Astrida | 4 | 64 | 9 | 2 | 2 |
| Betacab | 2 | 40 | 5 | 2 | 2 |
| Canutility | 8 | 120 | - | 2 | 2 |

Beachten Sie in diesem Beispiel Folgendes:

* In der ersten Kennzahl (`Min(UnitSales)`) ist der niedrigste Wert für `UnitSales` für den Kunden `Astrida` `4`. Die Zelle `Totals` in dieser Spalte gibt `2` zurück, da dieser Wert der niedrigste Wert für `UnitSales` im gesamten Datensatz ist.

* In der zweiten Kennzahl (`Min(UnitSales*UnitPrice)`) wird `64` für `Astrida` zurückgegeben. Dies ist der niedrigste Wert für diesen Kunden, wenn man `UnitSales` mit `UnitPrice` multipliziert. Die Zelle `Totals` in dieser Spalte gibt `40` zurück, da dieser Wert auch der niedrigste berechnete Wert im gesamten Datensatz ist.

* In der dritten Kennzahl (`Min(UnitSales, 2)`) ist der zweitniedrigste Wert für `UnitSales` für den Kunden `Astrida` `9`. Der Wert `4` wird in der Zeile `Totals` zurückgegeben, da dies der zweitniedrigste Wert von `UnitSales` für alle Kunden ist.

* Die vierte Kennzahl (`Min(TOTAL UnitSales)`) gibt den Wert `2` zurück. Dies ist der niedrigstmögliche Nicht-Null-Wert, der unabhängig von der Kundendimension gefunden wurde, daher geben alle Zeilen denselben Wert zurück. Wenn Sie jedoch den Kunden `Betacab` auswählen, gibt die Tabelle nur Werte für diesen Kunden zurück, in diesem Fall `2`, da dies der niedrigste `UnitSales` über alle Produkte für `Betacab` ist.

* Die fünfte Kennzahl (`Min({1} TOTAL UnitSales)`) gibt `2` zurück, unabhängig von dem im Feld `Customer` ausgewählten Wert, da die Kennzahl den niedrigsten Gesamtwert berechnet. Wenn Sie z. B. `Betacab` auswählen, gibt diese Spalte weiterhin den Wert `2` zurück.

## Beispiel – „Min“-Szenario zur Berechnung der niedrigsten Umsätze pro Monat

[](https://help.qlik.com/en-US/sense/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/BasicAggregationFunctions/min.htm)

#### Diagrammformel

Übersicht

Ein Datensatz enthält Produktumsatzzahlen nach Monat. Ein Vertriebsmanager möchte den minimalen Umsatzwert für jedes Produkt und den Monat, in dem dieser Wert erreicht wurde, ermitteln.

Öffnen Sie den Dateneditor und fügen Sie das Ladeskript unten in einen neuen Abschnitt ein.

Das Ladeskript umfasst:

* Datensatz, der in eine Datentabelle namens `Example` geladen wird

* Die folgenden Felder in der Datentabelle:

  * `Product`

  * `Sales`

  * `Month`

Ladeskript

```
Example:
Load * inline [
Product,Sales,Month
A, 500, 2024-01-01
A, 700, 2024-02-01
A, 600, 2024-03-01
B, 300, 2024-01-01
B, 800, 2024-02-01
B, 450, 2024-03-01
C, 550, 2024-01-01
C, 620, 2024-02-01
C, 710, 2024-03-01
];
```

Ergebnisse

Laden Sie die Daten und öffnen Sie ein Arbeitsblatt. Erstellen Sie eine neue Tabelle und fügen Sie die folgenden Felder als Dimensionen hinzu:

* `Product`

* `Month`

Erstellen Sie die folgende Kennzahl:

* `=If(Sales = Min(TOTAL <Product> Sales), Sales)`, um den minimalen Umsatz für jedes Produkt zu berechnen. Wählen Sie im Eigenschaftsfenster Add-Ons &gt; Datenverarbeitung aus. Deaktivieren Sie das Kontrollkästchen Nullwerte einschließen.

Results table

| Product | Month | If(Sales = Min(TOTAL &lt;Product&gt; Sales), Sales) |
| --- | --- | --- |
| A | 2024-01-01 | 500 |
| B | 2024-01-01 | 300 |
| C | 2024-01-01 | 550 |

Die Ergebnisse der Kennzahl liefern den minimalen Umsatzwert für jedes Produkt und den Monat, in dem dieser Wert erreicht wurde. Zum Beispiel hatte ` Product B  ` den niedrigsten Umsatz (`300`) in `2024-01-01`.

## Weitere Informationen

* [FirstSortedValue - Diagrammfunktion](https://help.qlik.com/de-DE/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/BasicAggregationFunctions/firstsortedvalue.htm)
* [RangeMin Skript- und Diagrammfunktion](https://help.qlik.com/de-DE/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/RangeFunctions/rangemin.htm)
* [Aggregierung mit Auswahlformeln](https://help.qlik.com/de-DE/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/SetAnalysis/set-analysis-expressions.htm)
* [Definieren des Aggregierungsbereichs](https://help.qlik.com/de-DE/sense/May2026/Subsystems/Hub/Content/Sense_Hub/ChartFunctions/define-aggregation-scope.htm)