# Laden von Daten aus Inline-Tabellen
Geben Sie manuell Daten in ein Skript ein, um eine Inline-Tabelle zu definieren.
Sie erstellen Inline-Tabellen, indem Sie Daten manuell in das Skript eingeben, anstatt eine Verbindung zu Dateien und Datenbanken herzustellen. Verwenden Sie die erforderliche Syntax, um anzugeben, dass der Skripttext als Inline-Daten interpretiert werden soll.
Mit einem grundlegenden Inline-Ladevorgang wird eine Tabelle erstellt und es werden die Datenfelder und Datensätze eingefügt.
## Gründe für die Verwendung von Inline-Ladevorgängen
Inline-Ladevorgänge können in verschiedenen Anwendungsfällen nützlich sein:
* Verwalten und Bearbeiten von Daten, ohne eine Verbindung zu externen Quellen zu benötigen.
* Ergänzen der vorhandenen Daten im Datenmodell. Sie können beispielsweise eine weitere Tabelle zu einem Datenmodell hinzufügen, das hauptsächlich aus Datenbankquellen besteht.
* Hinzufügen gewünschter Daten, um fortlaufendes Laden aus externen Quellen zu vermeiden. Das kann Zeit sparen, wenn Sie wissen, dass sich die Datenquelle zukünftig ändern könnte, aber die Datenwerte gleich bleiben.
* Einfache Verwendung zum Kopieren und Einfügen von Inhalten aus anderen Dateien im Skript. Beispielsweise .csv-Dateien oder -Tabellen aus Textverarbeitungsdokumenten.
* Erstellen von Testskripten, die rasch kopiert und eingefügt werden können.
## Einfaches Syntaxbeispiel
Das folgende Skript enthält einen einfachen Inline-Ladevorgang.
```
MyTable:
Load * Inline [Country, Year, Sales
Argentina, 2014, 66295.03
Argentina, 2015, 140037.89
Austria, 2014, 54166.09
Austria, 2015, 182739.87
];
```
Die folgende Syntax wird für den obigen Inline-Ladevorgang verwendet:
* Load \* Inline weist QlikView an, alle Felder aus der folgenden Inline-Tabelle zu laden.
* MyTable: definiert den Namen der Tabelle.
* Eckige Klammern umschließen die Daten.
* Die erste Zeile der load-Anweisung definiert die Datenfelder.
* Kommas trennen Datenfelder und Datensatzeinträge voneinander.
* Ein Strichpunkt beendet die load-Anweisung.
## Syntaxübersicht
### Benennen der Tabelle
Sie können einen Namen für die Inline-Tabelle genau wie für andere geladene Tabellen hinzufügen. Das Definieren des Tabellennamens ist optional.
Fügen Sie nach dem Namen der Tabelle einen Punkt ein.
### LOAD- und inline-Anweisungen
Eine Inline-Tabelle wird mit der inline-Bedingung geladen, wenn Sie die LOAD-Skriptanweisung verwenden. Die inline-Bedingung gibt an, dass der nachfolgende Text in der Tabelle Daten enthält, die manuell in den Editor eingegeben werden. Sofern Sie nichts anderes angeben, verwendet eine Inline-Tabelle das txt-Format, das der Struktur einer Textdatei mit Trennzeichen folgt.
Weitere Informationen zur LOAD-Anweisung finden Sie unter [Load](https://help.qlik.com/de-DE/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptRegularStatements/Load.htm).
### Umschließungen und Dateneingabe
Über eine inline-Bedingung eingegebene Daten müssen von bestimmten Zeichen umschlossen werden. Folgende Zeichenkombinationen werden für das Umschließen von Daten akzeptiert:
* Eckige Klammern: `[` und `]`
* Doppelte Anführungszeichen: `"` und `"`
* Einfache Anführungszeichen: `'` und `'`
* Rückwärts geneigte Hochkommas: `` ` `` und `` ` ``
Mithilfe des Zeichens, das Sie zum Umschließen verwenden, können Sie Inline-Daten laden, die konfliktierende Zeichen enthalten. Wenn Ihre Daten beispielsweise Datensätze mit eckigen Klammern enthalten, können Sie diese stattdessen mit Anführungszeichen oder rückwärts geneigten Hochkommas umschließen.
Ein Beispiel für alternative Umschließungen finden Sie unter [Beispiel – Alternative Datenumschließungen](https://help.qlik.com/de-DE/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExDataEnc).
Außer wenn Sie ein alternatives Tabellenformat angeben (Standard ist txt), wird Text zwischen Umschließungen auf die gleiche Weise wie der Inhalt einer Datei interpretiert. Wenn Sie beispielsweise in einer Textdatei eine neue Zeile beginnen würden, sollten Sie dies auch im Text einer inline-Bedingung tun, indem Sie bei der Skripteingabe die Eingabetaste drücken.
### Beenden des Inline-Ladevorgangs
Das Ende der Inline-load-Anweisung wird durch einen Strichpunkt angegeben.
### Datenumwandlungen
In einem einfachen Inline-Ladevorgang ohne Umwandlungen wird die Anzahl der Spalten durch die erste Zeile angegeben. Die im folgenden Beispiel geladene Tabelle enthält drei Spalten: `Product_ID`, `Supplier_Name` und `Product_Category`.
```
Products:
Load * Inline [
Product_ID, Supplier_Name, Product_Category
1, Paracel, Home Decor
2, PageWave, Electronics
3, Talarian, Software
4, Userland, Appliances
];
```
Sie können auch Umwandlungen durchführen und neue Spalten innerhalb der gleichen Inline-Tabelle erstellen. Sie können vorangehende Load-Befehle verwenden, und mehr als eine LOAD-Anweisung kann zum Laden der gleichen Tabelle verwendet werden.
Spezifische Beispiele finden Sie unter [Beispiele – Inline-Ladevorgänge mit Umwandlungen](https://help.qlik.com/de-DE/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExTransform).
### Konfigurieren der Formatspezifikation in einem Inline-Ladevorgang
Wie bei anderen geladenen Tabellen können Sie die Formatspezifikation der Inline-Tabelle mithilfe der Formatspezifikationselemente ändern. Die Formatspezifikation wird in Klammern hinzugefügt. Sie sollte nach den Datenumschließungen hinzugefügt werden, aber vor dem Strichpunkt, der die LOAD-Anweisung beendet. Zu den Anpassungen, die Sie hinzufügen können, zählen:
* Ändern des Trennzeichens von einem Komma in ein anderes Zeichen. Beispiele finden Sie unter [Beispiele – Alternative Trennzeichen](https://help.qlik.com/de-DE/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExDelimiter).
Siehe: [Delimiter](https://help.qlik.com/de-DE/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/delimiter.htm)
* Auslassen von Tabellenspaltenüberschriften. Ein Beispiel finden Sie unter [Beispiel – Auslassen von Spaltenkopfzeilen](https://help.qlik.com/de-DE/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExOmitLabels).
Siehe: [Labels](https://help.qlik.com/de-DE/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/labels.htm)
* Verwenden eines anderen Datenformats (z. B. festes Datensatzformat). Ein Beispiel finden Sie unter [Beispiel – Laden eines anderen Datentyps](https://help.qlik.com/de-DE/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExChangeFormat).
Siehe: [Tabellenformat](https://help.qlik.com/de-DE/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/table-format.htm)
InformationshinweisNicht alle Table format-Optionen werden für Inline-Ladevorgänge unterstützt.
* Zulassen von Inhalten mit mehreren Zeilen. Ein Beispiel finden Sie unter [Beispiel – Mehrzeiliger Inhalt](https://help.qlik.com/de-DE/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExMultLine).
Siehe: [Quotes](https://help.qlik.com/de-DE/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/quotes.htm)
Um mehrere Formatspezifikationselemente in der gleichen Tabelle zu verwenden, trennen Sie diese mit Kommas. Hier ein Beispiel:` (Delimiter is '|', no labels) `
Weitere Einzelheiten über Formatspezifikationen finden Sie unter [Formatoptionen](https://help.qlik.com/de-DE/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/format-specification-items.htm).
### Operatoren und andere Bedingungen
Da ein Inline-Ladevorgang eine LOAD-Anweisung ist, können Sie zudem andere Argumente für die LOAD-Anweisung im Inline-Ladevorgang kombinieren. Verwenden Sie beispielsweise die Bedingung where oder while, um je nach dem Text einer bestimmten Zeile zu definieren, ob sie geladen werden soll oder nicht.
Entsprechend können Sie auch Operatoren außerhalb des Textinhalts selbst verwenden. Mit Operatoren können Sie anpassen, wie Sie die Inline-Daten umwandeln, und Sie können auch definieren, ob bestimmte Daten geladen werden oder nicht.
Ein spezifisches Beispiel finden Sie unter [Beispiel – Operatoren für Umwandlungen und Bedingungen](https://help.qlik.com/de-DE/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#ExOpsAndClauses).
## Beispiel – Alternative Datenumschließungen
Sie können eckige Klammern, Anführungszeichen oder rückwärts geneigte Hochkommas verwenden, um einen Inline-Ladevorgang zu umschließen. In diesem Abschnitt wird dies anhand eines Beispiels gezeigt. Weitere Informationen finden Sie unter [Umschließungen und Dateneingabe](https://help.qlik.com/de-DE/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#Enclosure).
#### Ladeskript und Ergebnisse
Übersicht
Dieses Beispiel zeigt, wie Sie rückwärts geneigte Hochkommas zum Umschließen von Inline-Daten verwenden. Die Daten im Beispiel enthalten eckige Klammern, weshalb eckige Klammern als Umschließung für die LOAD-Anweisung inkompatibel sind.
Ladeskript
```
DataTable:
Load * inline
`
custom_property, date, amount
[11402], 1/1/2024, 92.99
[11403], 1/2/2024, 102.34
[11404], 1/3/2024, 50.26
[11405], 1/4/2024, 153.69
[11406], 1/5/2024, 75.62
`;
```
Ergebnisse
* `custom_property`
* `date`
* `amount`
Ergebnistabelle
| custom\_property | date | amount |
| --- | --- | --- |
| [11402] | 1/1/2024 | 92.99 |
| [11403] | 1/2/2024 | 102.34 |
| [11404] | 1/3/2024 | 50.26 |
| [11405] | 1/4/2024 | 153.69 |
| [11406] | 1/5/2024 | 75.62 |
## Beispiele – Alternative Trennzeichen
Sie können ein anderes Zeichen als ein Komma zum Trennen von Spaltenwerten in der Tabelle verwenden. Weitere Informationen finden Sie unter [Konfigurieren der Formatspezifikation in einem Inline-Ladevorgang](https://help.qlik.com/de-DE/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#FormatSpec).
#### Ladeskript und Ergebnisse
Übersicht
Das Ändern des Trennzeichens ist nützlich, wenn Daten in der Tabelle Kommas enthalten, was ansonsten den Wechsel zur nächsten Spalte in der Tabelle angäbe.
Dieses Beispiel enthält vier zu ladende Tabellen. Dies sind:
* Vier zu ladende Tabellen. Dies sind:
* Table1: Das Trennzeichen ist ein senkrechter Strich. Die Daten in der Spalte Phrase enthalten Kommas.
* Table2: Das Trennzeichen ist ein Punkt.
* Table3: Das Trennzeichen ist ein umgekehrter Schrägstrich.
* Table4: Das Trennzeichen in der Tabelle wird durch Drücken der Tabulatortaste auf der Tastatur gesetzt. Diese Option ist nützlich, wenn Sie eine Tabelle aus einem Textverarbeitungsprogramm kopieren und in das Skript einfügen.
Table1 zeigt einen praktischen Anwendungsfall für die Verwendung eines alternativen Trennzeichens. Die anderen Tabellen zeigen weitere Trennzeichenoptionen.
Ladeskript
```
Table1:
LOAD * INLINE [
ID|Phrase
1 | 'The transaction was complete, but the order has not yet shipped.'
2 | 'We need to confirm the following details: sales rep number, order status, and shipping priority.'
] (Delimiter is '|');
Table2:
LOAD * INLINE [
Num1:Chr1
1:A
2:B ] (Delimiter is ':');
Table3:
LOAD * INLINE [
Num2\Chr2
1\A
2\B ] (Delimiter is \\);
Table4:
LOAD * INLINE [
Num3 Chr3
1 A
2 B ] (Delimiter is '\t');
```
Ergebnisse
Ergebnistabelle: Table1Table1
| ID | Phrase |
| --- | --- |
| 1 | The transaction was complete, but the order has not yet shipped. |
| 2 | We need to confirm the following details: sales rep number, order status, and shipping priority. |
Ergebnistabelle: Table2Table2
| Num1 | Chr1 |
| --- | --- |
| 1 | A |
| 2 | B |
Ergebnistabelle: Table3Table3
| Num2 | Chr2 |
| --- | --- |
| 1 | A |
| 2 | B |
Ergebnistabelle: Table4Table4
| Num3 | Chr3 |
| --- | --- |
| 1 | A |
| 2 | B |
## Beispiel – Auslassen von Spaltenkopfzeilen
Bearbeiten Sie die Formatspezifikation, um eine Inline-Tabelle ohne Definieren von Spaltenkopfzeilen zu laden. Das geschieht über die labels-Spezifikation (die auf einen Wert von no labels festgelegt wird). Weitere Informationen finden Sie unter [Konfigurieren der Formatspezifikation in einem Inline-Ladevorgang](https://help.qlik.com/de-DE/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#FormatSpec).
Wenn Sie eine Tabelle laden, ohne Spaltennamen zu definieren, werden automatisch systemdefinierte Spaltennamen verwendet.
#### Ladeskript und Ergebnisse
Übersicht
Dieses Beispiel zeigt, wie Sie eine Inline-Tabelle ohne Definieren von Spaltennamen laden können.
Ladeskript
```
Expenses:
Load * inline
[
1,Category1,40566.49
2,Category2,3504.54
3,Category3,593206.30
] (no labels);
```
Ergebnisse
Ergebnistabelle
| @1 | @2 | @3 |
| --- | --- | --- |
| 1 | Category1 | 40566.49 |
| 2 | Category2 | 3504.54 |
| 3 | Category3 | 593206.30 |
## Beispiel – Laden eines anderen Datentyps
Dieses Beispiel zeigt, wie Sie eine Inline-Tabelle im festen Datensatzformat laden können. Siehe [Konfigurieren der Formatspezifikation in einem Inline-Ladevorgang](https://help.qlik.com/de-DE/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#FormatSpec).
#### Ladeskript und Ergebnisse
Übersicht
Dieses Beispielskript enthält Folgendes:
* Eine Inline-load-Anweisung, die die Tabelle DataTable definiert.
* Die Verwendung von fix (als Teil der Table format-Spezifikation), um anzugeben, dass die zu ladenden Daten ein festes Datensatzformat aufweisen.
Ladeskript
```
DataTable:
LOAD
"@1:4",
"@5:8",
"@9:12",
"@13:16"
INLINE [
a b c d
1 2 3 4
x y z w
] (fix, utf8, embedded labels);
```
Ergebnisse
Ergebnistabelle
| a | b | c | d |
| --- | --- | --- | --- |
| 1 | 2 | 3 | 4 |
| x | y | z | w |
## Beispiel – Mehrzeiliger Inhalt
Dieses Beispiel zeigt, wie Sie mehrzeiligen Feldinhalt in eine Inline-Tabelle eingeben können. Siehe [Konfigurieren der Formatspezifikation in einem Inline-Ladevorgang](https://help.qlik.com/de-DE/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#FormatSpec).
#### Ladeskript und Ergebnisse
Übersicht
Dieses Beispielskript enthält Folgendes:
* Einen einfachen Inline-Ladevorgang zum Definieren der Tabelle T1.
* Verwendung des Spezifizierers Quotes (mit dem Wert msq) zur Unterstützung von mehrzeiligem Inhalt.
* Längenwerte sind in Fuß und Zoll angegeben.
* Das doppelte Anführungszeichen (") gibt das Ende eines mehrzeiligen Eintrags an. In diesem Beispiel wird das gleiche Symbol auch zum Angeben von Zollwerten verwendet. Damit werden die Syntax und das resultierende Verhalten gezeigt, wenn Sie beides in der gleichen LOAD-Anweisung verwenden müssen. Grundsätzlich gibt die Eingabe des Symbols " für zwei aufeinanderfolgende Zeichen ("") an, dass der Code als einzelne Textinstanz des Symbols interpretiert werden soll.
Ladeskript
```
T1:
Load *, recno() as ID inline [
Length
"1' 2""
22' 10"""
14' 8" ] (msq);
```
Ergebnisse
Um mehrzeiligen Inhalt wie vorgesehen anzuzeigen, müssen Sie Mehrzeilige Zellen für das Diagramm in der Konfiguration von Eigenschaften... anpassen.
Ergebnistabelle
| ID | Length |
| --- | --- |
| 1 | 1' 2"
22' 10" |
| 2 | 14' 8" |
In der obigen Tabelle enthält der Datensatz mit einem ID-Wert von 1 mehrzeiligen Inhalt.
## Beispiele – Inline-Ladevorgänge mit Umwandlungen
Diese Beispiele zeigen, wie Sie Berechnungen für Felder durchführen können, die inline geladen werden, um neue Felder im Datenmodell zu erstellen.
Weitere Informationen finden Sie unter [Datenumwandlungen](https://help.qlik.com/de-DE/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#Transform).
#### Beispiel: Einfaches Umbenennen eines Felds
Ladeskript
```
ORDERS:
Load Original as Updated,
* Inline
[
Original
ProductA
ProductB
ProductC
];
```
Ergebnisse
Ergebnistabelle
| Original | Updated |
| --- | --- |
| ProductA | ProductA |
| ProductB | ProductB |
| ProductC | ProductC |
#### Beispiel: Einfaches Einfügen eines ID-Felds
Übersicht
Dieses Beispiel zeigt, wie Sie ein berechnetes Feld definieren können, um die ID jeder Datenzeile anzugeben, ohne jeden ID-Wert manuell einzugeben.
Ladeskript
```
ORDERS:
Load RowNo() as ID,
* Inline
[
ProductName
A
B
C
D
E
];
```
Ergebnisse
Ergebnistabelle
| ID | ProductName |
| --- | --- |
| 1 | A |
| 2 | B |
| 3 | C |
| 4 | D |
| 5 | E |
#### Beispiel: Konfigurieren von LOAD-Anweisungen zum Handhaben von Umwandlungen
Übersicht
Dieses Beispiel zeigt mehrere Weisen, auf die eine einfache Umwandlung auf Inline-Daten angewendet werden kann. Sie können eine oder mehrere LOAD-Anweisungen verwenden und die Syntax auf verschiedene Arten konfigurieren, um zu definieren, ob eine Umwandlung das ursprüngliche Feld ersetzt oder ob sowohl das ursprüngliche als auch neue Felder geladen werden.
Achten Sie besonders auf die Variationen im folgenden Beispiel und darauf, wie sie sich auf die Ausgabe auswirken:
* Anzahl der LOAD-Anweisungen innerhalb der Tabelle.
* Vorliegen oder Fehlen des \*-Symbols (lädt alle nachfolgenden Felder)
* Vorliegen oder Fehlen von Kommas (,-Symbol).
Dieses Beispielskript enthält Folgendes:
* Vier Tabellen, die alle die gleichen Daten referenzieren. Die Feldnamen sind verschieden.
* DerivedYears1: Verwendet zwei LOAD-Anweisungen, um eine Inline-Spalte und eine Spalte mit einer Umwandlung der Inline-Spalte zu laden.
* DerivedYears2: Verwendet zwei LOAD-Anweisungen. Das Skript lädt eine Inline-Spalte und dann ein berechnetes Feld, das aus der ursprünglichen Spalte umgewandelt wurde. Mit der zweiten LOAD-Anweisung wird die ursprüngliche Spalte nicht in die Tabelle geladen, was effektiv bewirkt, dass das neue Feld das ursprüngliche Feld ersetzt.
* DerivedYears3: Verwendet eine einzige LOAD-Anweisung, um sowohl die ursprüngliche Inline-Spalte als auch eine umgewandelte Spalte zu laden.
* DerivedYears4: Verwendet eine einzelne LOAD-Anweisung, um ein Inline-Feld und eine Umwandlung dieses ursprünglichen Felds zu definieren. Nur das umgewandelte Feld wird in die Tabelle geladen.
Ladeskript
```
DerivedYears1:
Load *,
Year(initial_date1) as derived_year1
;
Load
* inline [
initial_date1
'1/1/2022'
'1/1/2023'
'1/1/2024'
];
DerivedYears2:
Load
Year(initial_date2) as derived_year2
;
Load
* inline [
initial_date2
'1/1/2022'
'1/1/2023'
'1/1/2024'
];
DerivedYears3:
Load Year(initial_date3) as derived_year3,
* inline [
initial_date3
'1/1/2022'
'1/1/2023'
'1/1/2024'
];
DerivedYears4:
Load Year(initial_date4) as derived_year4
inline [
initial_date4
'1/1/2022'
'1/1/2023'
'1/1/2024'
];
```
Ergebnisse
Ergebnistabelle: DerivedYears1DerivedYears1
| initial\_date1 | derived\_year1 |
| --- | --- |
| 1/1/2022 | 2022 |
| 1/1/2023 | 2023 |
| 1/1/2024 | 2024 |
Ergebnistabelle: DerivedYears2DerivedYears2
| derived\_year2 |
| --- |
| 2022 |
| 2023 |
| 2024 |
Ergebnistabelle: DerivedYears3DerivedYears3
| initial\_date3 | derived\_year3 |
| --- | --- |
| 1/1/2022 | 2022 |
| 1/1/2023 | 2023 |
| 1/1/2024 | 2024 |
Ergebnistabelle: DerivedYears4DerivedYears4
| derived\_year4 |
| --- |
| 2022 |
| 2023 |
| 2024 |
#### Beispiel: Ändern von Feldinhalt
Übersicht
Angenommen, Sie fügen Informationen aus einer großen Textdatei in den Skript-Editor ein, möchten die Dateneinträge im Datensatz aber noch weiter verarbeiten. Sie möchten beispielsweise bestimmte Zeichen und Vorzeichen entfernen und alle Wörter mit einem Großbuchstaben beginnen lassen.
Dieses Beispielskript enthält Folgendes:
* Eine Inline-Tabelle, Transformations, in der eine Umwandlung definiert ist, um den Textinhalt eines Felds zu ändern. Der umzuwandelnde Text wird danach hinzugefügt.
* Zwei LOAD-Anweisungen. Mit der Konfiguration im Beispiel wird nur das abgeleitete Feld ProductName\_Trimmed in die Tabelle geladen.
Ladeskript
```
Transformations:
Load
Capitalize(TextBetween(OrigColumn, '{','}')) as ProductName_Trimmed;
Load * inline [
OrigColumn
Product: {soft drinks and other beverages}
Product: {snack food}
Product: {electronics and video games}
];
```
Ergebnisse
Ergebnistabelle
| ProductName\_Trimmed |
| --- |
| Soft Drinks And Other Beverages |
| Snack Food |
| Electronics And Video Games |
## Beispiel – Operatoren für Umwandlungen und Bedingungen
Sie können Operatoren verwenden, um Umwandlungen und bestimmte Bedingungen in der LOAD-Anweisung zu definieren. Weitere Informationen finden Sie unter [Operatoren und andere Bedingungen](https://help.qlik.com/de-DE/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/inline-loads-qv.htm#OpsAndClauses).
[Operatoren](https://help.qlik.com/de-DE/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/Operators/operators.htm)
#### Ladeskript und Ergebnisse
Übersicht
Dieses Beispielskript enthält Folgendes:
* Einen einfachen Inline-Ladevorgang zum Definieren der Tabelle Purchases.
* Die Einfügung eines berechneten Felds, OrderSize. Dieses Feld ist eine Umwandlung des Felds amount aus dem Inline-Datensatz. Es ordnet Käufe in die Kategorien „klein“ oder „groß“ ein, je nachdem, ob der Betrag 2000,00 $ überschreitet oder nicht.
* Eine where-Bedingung, die verhindert, dass Datensätze geladen werden, wenn amount weniger als 0,05 $ beträgt.
Ladeskript
```
Purchases:
Load
If(amount<2000,'Small Purchase','Large Purchase') as OrderSize,
* inline
[
ID, amount
1,2660.39
2,100.01
3,500.42
4,5023.99
5,0.04
6,2002.39
7,31034.53
8,1643.58
9,3993.65
10,614.34
11,675.93
]
WHERE
amount>1
;
```
Ergebnisse
Ergebnistabelle
| ID | amount | OrderSize |
| --- | --- | --- |
| 1 | 2660.39 | Large Purchase |
| 2 | 100.01 | Small Purchase |
| 3 | 500.42 | Small Purchase |
| 4 | 5023.99 | Large Purchase |
| 6 | 2002.39 | Large Purchase |
| 7 | 31034.53 | Large Purchase |
| 8 | 1643.58 | Small Purchase |
| 9 | 3993.65 | Large Purchase |
| 10 | 614.34 | Small Purchase |
| 11 | 675.93 | Small Purchase |
In der obigen Tabelle wurde die Transaktion mit einer ID von 5 nicht in die Tabelle geladen. Dies liegt daran, dass der Wert für amount weniger als 0,05 $ beträgt.
## Beispiel – Erstellen von Null-Werten in einer Inline-Tabelle
Dieses Beispiel zeigt, wie Sie die Variable NullInterpret verwenden können, um Null-Werte in Ihren Inline-Daten zu erstellen.
[NullInterpret](https://help.qlik.com/de-DE/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/ValueHandlingVariables/NullInterpret.htm)
#### Ladeskript und Ergebnisse
Übersicht
Dieses Beispielskript enthält Folgendes:
* Einen einfachen Inline-Ladevorgang zum Definieren der Tabelle T2.
* Die Variable NullInterpret, die als zwei einzelne Anführungszeichen definiert ist. Beim Laden des Skripts werden Datensätze, die diesen Wert enthalten, als Null-Werte verarbeitet.
Ladeskript
```
set nullinterpret = '';
T2:
Load * inline [
Test
''
x ];
```
Ergebnisse
Ergebnistabelle
| Test |
| --- |
| x |
In der obigen Tabelle ist der erste Datensatz ein Null-Wert. Daher wird er nicht in die Visualisierung eingeschlossen. Null-Werte in Tabellen mit zusätzlichen Dimensionen würden mit einem --Symbol bezeichnet.
## Weitere Beispiele
Weitere Beispiele finden Sie unter [Load](https://help.qlik.com/de-DE/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptRegularStatements/Load.htm).
## Weitere Informationen
* [Load](https://help.qlik.com/de-DE/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptRegularStatements/Load.htm)
* [Formatoptionen](https://help.qlik.com/de-DE/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Scripting/ScriptSpecifiers/format-specification-items.htm)
* [Inline-Assistent](https://help.qlik.com/de-DE/qlikview/May2024/Subsystems/Client/Content/QV_QlikView/Inline_Data_Wizard.htm)